server_config/flake.nix

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.05";
    unstable.url = "github:nixos/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";

    flake-utils.url = "github:numtide/flake-utils";

    vpsadminos.url = "github:vpsfreecz/vpsadminos";

    homepage.url = "git+https://git.posixlycorrect.com/fabian/homepage.git?ref=master";

    conduwuit = {
      url = "github:girlbossceo/conduwuit?ref=v0.4.5";
      #FIXME: Podrá volver a "nixpkgs" una vez que rocksdb.enableLiburing llegue a stable
      inputs.nixpkgs.follows = "unstable";
    };

    mediawikiSkinCitizen = {
      url = "github:StarCitizenTools/mediawiki-skins-Citizen/v2.27.0";
      flake = false;
    };

    authentik-nix = {
      url = "github:nix-community/authentik-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = flakes @ {
    self,
    nixpkgs,
    unstable,
    home-manager,
    impermanence,
    flake-utils,
    vpsadminos,
    homepage,
    conduwuit,
    mediawikiSkinCitizen,
    authentik-nix,
  }: let
    system = "x86_64-linux";

    pkgs = importPkgs nixpkgs;

    importPkgs = flake:
      import flake {
        inherit system;

        config = import ./pkgs/config nixpkgs.lib;
        overlays = [self.overlays.default];
      };

    local = import ./pkgs;
  in
    with pkgs.lib; {
      formatter.${system} = pkgs.alejandra;
      packages.${system} = pkgs.local;

      overlays.default = final: prev: let
        locals = local {
          inherit final prev flakes;
        };
      in
        {
          local = locals;
          unstable = importPkgs unstable;
        }
        // locals.override;

      nixosConfigurations.vps = makeOverridable nixpkgs.lib.nixosSystem {
        inherit pkgs system;

        specialArgs = {
          inherit flakes;
        };

        modules = singleton ./sys;
      };
    };
}