{ lib, pkgs, ... }:
with lib; {
  static = false; # !!!!
  namespaced = true;

  packages = with pkgs; [
    (quartus-prime-lite.override { supportedDevices = [ "Cyclone V" ]; })
    binutils
    gcc
    gnumake
    gtkwave
    verilator
  ];

  hm = {
    # QGtkStyle could not resolve GTK. Make sure you have installed the proper libraries.
    home.sessionVariables.LD_LIBRARY_PATH = "${pkgs.gtk2}/lib";

    # Evita GC
    xdg.configFile."quartus-inputs".text = let
      inherit (pkgs) requireFile;
      homepage = "https://fpgasoftware.intel.com";
      version = "20.1.1.720";
      url = "${homepage}/${versions.majorMinor version}/?edition=lite&platform=linux";

      inputs = [
        (requireFile {
          name = "QuartusLiteSetup-${version}-linux.run";
          sha256 = "0mjp1rg312dipr7q95pb4nf4b8fwvxgflnd1vafi3g9cshbb1c3k";
          inherit url;
        })

        (requireFile {
          name = "ModelSimSetup-${version}-linux.run";
          sha256 = "1cqgv8x6vqga8s4v19yhmgrr886rb6p7sbx80528df5n4rpr2k4i";
          inherit url;
        })

        (requireFile {
          name = "cyclonev-${version}.qdz";
          sha256 = "11baa9zpmmfkmyv33w1r57ipf490gnd3dpi2daripf38wld8lgak";
          inherit url;
        })
      ];
    in concatStringsSep "\n" inputs;


    # dice soto que ponga esto globalmente si quiero nightmode en todo
    # Usar gtk en aplicaciones de jvm
    home.sessionVariables._JAVA_OPTIONS = concatStringsSep " " [
      "-Dawt.useSystemAAFontSettings=on"
      "-Dswing.aatext=true"
      "-Dswing.defaultlaf=com.sun.java.swing.plaf.gtk.GTKLookAndFeel"
      "-Dswing.crossplatformlaf=com.sun.java.swing.plaf.gtk.GTKLookAndFeel"
    ];

    gtk = {
      enable = true;

      gtk2.extraConfig = ''
        gtk-toolbar-style=GTK_TOOLBAR_BOTH_HORIZ
        gtk-menu-images=1
        gtk-button-images=1
      '';

      font = {
        package = pkgs.noto-fonts;
        name = "Noto Sans Regular";
        #size = 14; <- caga layout de páginas
      };

      theme = {
        package = pkgs.materia-theme;
        name = "Materia-dark";
      };
    };

    qt = {
      enable = true;
      platformTheme = "gtk";
    };
  };
}