modularize gui

home/modules/default.nix

@@ -11,5 +11,6 @@
     ./steam
     ./yubikey.nix
     ./browsers.nix
+    ./gui
   ];
 }

home/modules/gui/autorandr.nix

@@ -0,0 +1,32 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.local.gui;
+in {
+  programs.autorandr = {
+    profiles."default" = {
+      fingerprint =
+        mapAttrs
+        (monitorId: monitor: monitor.fingerprint)
+        cfg.monitors;
+
+      config =
+        mapAttrs (
+          monitorId:
+            filterAttrs
+            (k: v:
+              !elem k [
+                #list of options to exclude from this list
+                "fingerprint"
+                "initialI3Workspace"
+                "monitorId"
+              ])
+        )
+        cfg.monitors;
+    };
+  };
+}

home/modules/gui/default.nix

@@ -0,0 +1,116 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}:
+with lib; let
+  cfg = config.local.gui;
+  monitorType = {setName}: (
+    types.submodule ({name ? null, ...}: {
+      options = {
+        monitorId = mkOption {
+          type = types.str;
+          example = "DP-1";
+          readOnly = true;
+          internal = true;
+        };
+        primary = mkOption {
+          type = types.bool;
+          default = false;
+          description = "is primary monitor";
+          example = "true";
+        };
+        position = mkOption {
+          type = types.str;
+          example = "0x0";
+        };
+        mode = mkOption {
+          type = types.str;
+          description = "resolution";
+          default = "1920x1080";
+          example = "1920x1080";
+        };
+        rate = mkOption {
+          type = types.str;
+          description = "refresh rate";
+          example = "143.85";
+        };
+        rotate = mkOption {
+          type = types.str;
+          default = "normal";
+          example = "left";
+        };
+        fingerprint = mkOption {
+          type = types.str;
+          example = "00ffffffffffff003669a03bd4040000231e0104a5341d783bd005ac5048a627125054bfcf00814081809500714f81c0b30001010101023a801871382d40582c450009252100001e0882805070384d400820f80c09252100001a000000fd003090b4b422010a202020202020000000fc004d53492047323443340a20202001a2020320f14d010304131f120211900e0f1d1e230907078301000065030c001000866f80a0703840403020350009252100001a0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000e9";
+        };
+        initialI3Workspace = mkOption {
+          type = types.nullOr types.int;
+          default = null;
+          example = 1;
+        };
+      };
+      config = optionalAttrs setName {
+        # make this better later
+        monitorId = name;
+      };
+    })
+  );
+in {
+  options.local.gui = {
+    enable = mkEnableOption "GUI settings";
+    primaryMonitor = mkOption {
+      type = monitorType {setName = false;};
+      readOnly = true;
+      internal = true;
+    };
+    monitors = mkOption {
+      type = types.attrsOf (monitorType {setName = true;});
+    };
+    displayBatteryLevel = mkOption {
+      type = types.bool;
+      default = false;
+      description = "show battery level on polybar";
+      example = "true";
+    };
+  };
+
+  imports = [
+    ./autorandr.nix
+    ./fonts.nix
+    ./i3.nix
+    ./polybar.nix
+    ./startx.nix # move to ly once 24.11 comes out :(
+    ./picom.nix
+  ];
+
+  config = let
+    primaryMonitors =
+      filter (monitor: monitor.primary)
+      (attrValues cfg.monitors);
+  in
+    mkIf cfg.enable {
+      assertions = [
+        {
+          assertion = length primaryMonitors == 1;
+          message = "Exactly one (1) primary monitor is requiered.";
+        }
+      ];
+
+      local.gui.primaryMonitor = head primaryMonitors;
+
+      xsession = {
+        enable = true;
+        windowManager.i3.enable = true;
+      };
+
+      programs.autorandr.enable = true;
+      services = {
+        dunst.enable = true;
+        betterlockscreen.enable = true;
+        polybar.enable = true;
+        picom.enable = true;
+      };
+    };
+}

home/modules/gui/fonts.nix

@@ -0,0 +1,12 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  fonts.fontconfig.enable = true;
+
+  home.packages = with pkgs; [
+    jetbrains-mono
+  ];
+}

home/modules/gui/gtk.nix

@@ -0,0 +1,11 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  home.packages = with pkgs; [
+    gruvbox-dark-icons-gtk
+    libsForQt5.breeze-gtk
+  ];
+}

home/modules/gui/i3.nix

@@ -0,0 +1,103 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; {
+  xsession.windowManager.i3 = {
+    package = pkgs.i3-gaps;
+
+    config = let
+      mod = "Mod4";
+    in {
+      modifier = mod;
+
+      fonts = {
+        names = ["JetBrains Mono"];
+        style = "Regular";
+        size = 8.0;
+      };
+
+      gaps = {
+        inner = 10;
+        outer = -10;
+      };
+
+      window = {
+        hideEdgeBorders = "both";
+      };
+
+      colors = {
+        focused = {
+          background = "#222222";
+          border = "#4c7899";
+          childBorder = "#222222";
+          indicator = "#292d2e";
+          text = "#888888";
+        };
+      };
+
+      # mkOptionDefault hace que se ponga la config por default
+      # y se sobreescriba las cosas que pongo acá
+      # NO QUITARLO. ver man home-configuration.nix
+      keybindings = mkOptionDefault {
+        "${mod}+Return" = "exec ${pkgs.kitty}/bin/kitty ${pkgs.tmux}/bin/tmux";
+        "${mod}+Tab" = "focus right";
+        "${mod}+Shift+Tab" = "focus left";
+        "${mod}+Shift+s" = "exec ${pkgs.maim}/bin/maim -s -u | ${pkgs.xclip}/bin/xclip -selection clipboard -t image/png -i";
+        "${mod}+Shift+w" = "move workspace to output right";
+        "${mod}+l" = "exec ${pkgs.betterlockscreen}/bin/betterlockscreen -l";
+      };
+
+      startup = [
+        {
+          command = "${pkgs.xss-lock}/bin/xss-lock --transfer-sleep-lock -- ${pkgs.i3lock}/bin/i3lock --nofork";
+          notification = false;
+        }
+        {
+          command = "${pkgs.networkmanagerapplet}/bin/nm-applet";
+          notification = false;
+        }
+        # sería nice hostear esta imagen en el server y fetchearla si no existe
+        {
+          command = "${pkgs.feh}/bin/feh --bg-fill ${config.home.homeDirectory}/Pictures/wallpapers/jupiter.png";
+          notification = false;
+          always = true;
+        }
+        {
+          command = "${pkgs.i3-gaps}/bin/i3-msg 'workspace 1; exec ${pkgs.firefox}/bin/firefox'";
+        }
+        {
+          command = "${pkgs.i3-gaps}/bin/i3-msg 'workspace 2; exec ${pkgs.tdesktop}/bin/telegram-desktop'";
+        }
+        #{
+        #  command = "${pkgs.i3-gaps}/bin/i3-msg 'workspace 2; exec ${pkgs.element-desktop}/bin/element-desktop'";
+        #}
+        {
+          command = "${pkgs.systemd}/bin/systemctl --user restart polybar.service";
+          notification = false;
+          always = true;
+        }
+        {
+          command = "${pkgs.autorandr}/bin/autorandr -c";
+          notification = false;
+          always = true;
+        }
+      ];
+
+      workspaceOutputAssign =
+        mapAttrsToList (
+          monitorId: v:
+            {
+              output = monitorId;
+            }
+            // optionalAttrs (v.initialI3Workspace != null) {
+              workspace = toString v.initialI3Workspace;
+            }
+        )
+        config.local.gui.monitors;
+      bars = [];
+    };
+  };
+}

home/modules/gui/picom.nix

@@ -0,0 +1,41 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  services.picom = {
+    fade = true;
+    fadeSteps = [0.1 0.1];
+    fadeDelta = 10;
+    settings = {
+      animations = [
+        {
+          triggers = [
+            "open"
+            "show"
+          ];
+
+          preset = "appear";
+          duration = "1";
+        }
+        {
+          triggers = [
+            "close"
+            "hide"
+          ];
+
+          preset = "disappear";
+          duration = "1";
+        }
+        {
+          triggers = [
+            "geometry"
+          ];
+          preset = "geometry-change";
+          duration = "1";
+        }
+      ];
+    };
+  };
+}

home/modules/gui/polybar.nix

@@ -0,0 +1,460 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; {
+  services.polybar = {
+    package = pkgs.polybarFull;
+    script = ''
+      # Terminate already running bar instances
+      killall -q polybar
+
+      # Wait until the processes have been shut down
+      while pgrep -u $UID -x polybar >/dev/null; do sleep 1; done
+
+      # Launch Polybar, using default config location ~/.config/polybar/config
+      polybar -r main & polybar -r secondary &
+    '';
+
+    settings = {
+      "colors" = {
+        # background = "\${xrdb:color0:#222}";
+        background = "#AA000000";
+        background-alt = "#00000000";
+        # foreground = "\${xrdb:color7:#222}";
+        foreground = "#ffffff";
+        foreground-alt = "#ffffff";
+        primary = "#ffffff";
+        secondary = "#e60053";
+        alert = "#bd2c40";
+      };
+
+      "bar/main" = {
+        monitor = config.local.gui.primaryMonitor.monitorId;
+        width = "100%";
+        height = 30;
+        offset-x = "0%";
+        offset-y = "0%";
+        radius = 0.0;
+        fixed-center = false;
+
+        background = "\${colors.background}";
+        foreground = "\${colors.foreground}";
+
+        line-size = 1;
+        line-color = "#f0000000";
+
+        border-size = 0;
+        border-color = "#00000000";
+
+        padding-left = 0;
+        padding-right = 0;
+
+        module-margin-left = 1;
+        module-margin-right = 1;
+
+        # font-0 = "fixed:pixelsize=10;1";
+        font-0 = "JetBrains Mono Light:size=10;0";
+        font-1 = "unifont:fontformat=truetype:size=8:antialias=false;0";
+        font-2 = "siji:pixelsize=10;1";
+        # font-2 = "FontAwesome5Free:style=Regular:size=10;4";
+
+        modules-left = "i3";
+        modules-center = "xwindow";
+        modules-right = "xkeyboard pulseaudio filesystem memory cpu temperature gputemperature nvmetemperature wlan eth date semanatec";
+        separator = "|";
+
+        tray-position = "right";
+        tray-padding = 2;
+
+        # To allow other windows to be placed above the bar, or to avoid having the bar visible when in fullscreen mode,
+        # you need to use the following two parameters. Note that it will tell the window manager to back off so no
+        # area will be reserved, etc.
+        #
+        # wm-restack = "i3";
+        # override-redirect = true;
+
+        cursor-click = "pointer";
+        cursor-scroll = "ns-resize";
+      };
+
+      "bar/secondary" = {
+        monitor = head (attrNames (filterAttrs (monitorId: v:
+          !v.primary)
+        config.local.gui.monitors)); # this is bad. will fail if more than 2 monitors. this sets all monitors other than the primary one for this bar.
+        "inherit" = "bar/main";
+
+        modules-left = "i3";
+        modules-center = "xwindow";
+        modules-right = "xkeyboard pulseaudio date";
+        tray-position = "none";
+      };
+
+      "module/xwindow" = {
+        type = "internal/xwindow";
+        label = "%title:0:30:...%";
+      };
+
+      "module/xkeyboard" = {
+        type = "internal/xkeyboard";
+        blacklist-0 = "num lock";
+
+        format-prefix = "";
+        format-prefix-foreground = "\${colors.foreground-alt}";
+
+        label-layout = "%layout%";
+
+        label-indicator-padding = 2;
+        label-indicator-margin = 1;
+        label-indicator-background = "\${colors.secondary}";
+      };
+
+      "module/filesystem" = {
+        type = "internal/fs";
+        interval = 10;
+
+        mount-0 = "/";
+
+        label-mounted = "%{F#0a81f5}%mountpoint%%{F-}: %used%/%total%";
+        label-unmounted = "";
+      };
+
+      "module/i3" = {
+        type = "internal/i3";
+        format = "<label-state> <label-mode>";
+        index-sort = true;
+        wrapping-scroll = false;
+
+        # Only show workspaces on the same output as the bar
+        # pin-workspaces = true
+
+        label-mode-padding = 1;
+        label-mode-foreground = "#000";
+        label-mode-background = "\${colors.primary}";
+
+        # focused = Active workspace on focused monitor
+        label-focused = "%index%";
+        label-focused-background = "\${colors.background}";
+        label-focused-underline = "\${colors.primary}";
+        label-focused-padding = 1;
+
+        # unfocused = Inactive workspace on any monitor
+        label-unfocused = "%index%";
+        label-unfocused-padding = 1;
+
+        # visible = Active workspace on unfocused monitor
+        label-visible = "%index%";
+        label-visible-background = "\${self.label-focused-background}";
+        label-visible-underline = "\${self.label-focused-underline}";
+        label-visible-padding = "\${self.label-focused-padding}";
+
+        # urgent = Workspace with urgency hint set
+        label-urgent = "%index%";
+        label-urgent-background = "\${colors.alert}";
+        label-urgent-padding = 1;
+      };
+
+      "module/xbacklight" = {
+        type = "internal/xbacklight";
+
+        format = "<label> <bar>";
+        label = "BL";
+
+        bar-width = 10;
+        bar-indicator = "|";
+        bar-indicator-foreground = "#fff";
+        bar-indicator-font = 2;
+        bar-fill = "─";
+        bar-fill-font = 2;
+        bar-fill-foreground = "#9f78e1";
+        bar-empty = "─";
+        bar-empty-font = 2;
+        bar-empty-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/backlight-acpi" = {
+        "inherit" = "module/xbacklight";
+        type = "internal/backlight";
+        card = "intel_backlight";
+      };
+
+      "module/cpu" = {
+        type = "internal/cpu";
+        interval = 2;
+        format-prefix = "cpu ";
+        format-prefix-foreground = "\${colors.foreground-alt}";
+        label = "%percentage:2%%";
+      };
+
+      "module/memory" = {
+        type = "internal/memory";
+        interval = 2;
+        format-prefix = "mem ";
+        format-prefix-foreground = "\${colors.foreground-alt}";
+        label = "%percentage_used%%";
+      };
+
+      "module/wlan" = {
+        type = "internal/network";
+        interface = "wlp7s0";
+        interval = 3.0;
+
+        format-connected = "<ramp-signal> <label-connected>";
+        label-connected = "%essid%";
+
+        format-disconnected = "";
+        # format-disconnected = "<label-disconnected>";
+        # format-disconnected-underline = "\${self.format-connected-underline}";
+        # label-disconnected = "%ifname% disconnected";
+        # label-disconnected-foreground = "\${colors.foreground-alt}";
+
+        ramp-signal-0 = "";
+        ramp-signal-1 = "";
+        ramp-signal-2 = "";
+        ramp-signal-3 = "";
+        ramp-signal-4 = "";
+        ramp-signal-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/eth" = {
+        type = "internal/network";
+        interface = "enp8s0";
+        interval = 3.0;
+
+        format-connected-prefix = "";
+        format-connected-prefix-foreground = "\${colors.foreground-alt}";
+        label-connected = "%local_ip%";
+
+        format-disconnected = "";
+        # format-disconnected = "<label-disconnected>";
+        # format-disconnected-underline = "\${self.format-connected-underline}";
+        # label-disconnected = "%ifname% disconnected";
+        # label-disconnected-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/date" = {
+        type = "internal/date";
+        interval = 1;
+
+        date = " %d/%m/%Y";
+        date-alt = " %c";
+
+        time = "%H:%M";
+        time-alt = " [%s]";
+
+        format-prefix = "";
+        format-prefix-foreground = "\${colors.foreground-alt}";
+
+        label = "%date% %time%";
+      };
+
+      #      "module/semanatec" = {
+      #        type = "custom/script"
+      #        exec = "/home/fabian/bin/semanatec/target/release/semanatec"
+      #        interval = 3600
+      #        format-prefix = ""
+      #      };
+
+      "module/pulseaudio" = {
+        type = "internal/pulseaudio";
+
+        format-volume = "<label-volume>";
+        label-volume = "vol %percentage%%";
+        label-volume-foreground = "\${root.foreground}";
+
+        label-muted = "vol 0%";
+        label-muted-foreground = "\${root.foreground}";
+
+        bar-volume-width = 10;
+        bar-volume-foreground-0 = "#55aa55";
+        bar-volume-foreground-1 = "#55aa55";
+        bar-volume-foreground-2 = "#55aa55";
+        bar-volume-foreground-3 = "#55aa55";
+        bar-volume-foreground-4 = "#55aa55";
+        bar-volume-foreground-5 = "#f5a70a";
+        bar-volume-foreground-6 = "#ff5555";
+        bar-volume-gradient = false;
+        bar-volume-indicator = "|";
+        bar-volume-indicator-font = 2;
+        bar-volume-fill = "─";
+        bar-volume-fill-font = 2;
+        bar-volume-empty = "─";
+        bar-volume-empty-font = 2;
+        bar-volume-empty-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/alsa" = {
+        type = "internal/alsa";
+
+        format-volume = "<label-volume> <bar-volume>";
+        label-volume = "VOL";
+        label-volume-foreground = "\${root.foreground}";
+
+        format-muted-prefix = "vol ";
+        format-muted-foreground = "\${colors.foreground-alt}";
+        label-muted = "sound muted";
+
+        bar-volume-width = 10;
+        bar-volume-foreground-0 = "#55aa55";
+        bar-volume-foreground-1 = "#55aa55";
+        bar-volume-foreground-2 = "#55aa55";
+        bar-volume-foreground-3 = "#55aa55";
+        bar-volume-foreground-4 = "#55aa55";
+        bar-volume-foreground-5 = "#f5a70a";
+        bar-volume-foreground-6 = "#ff5555";
+        bar-volume-gradient = false;
+        bar-volume-indicator = "|";
+        bar-volume-indicator-font = 2;
+        bar-volume-fill = "─";
+        bar-volume-fill-font = 2;
+        bar-volume-empty = "─";
+        bar-volume-empty-font = 2;
+        bar-volume-empty-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/battery" = {
+        type = "internal/battery";
+        battery = "BAT0";
+        adapter = "ADP1";
+        full-at = 98;
+
+        format-charging = "<animation-charging> <label-charging>";
+        format-charging-underline = "#ffb52a";
+
+        format-discharging = "<animation-discharging> <label-discharging>";
+        format-discharging-underline = "\${self.format-charging-underline}";
+
+        format-full-prefix = " ";
+        format-full-prefix-foreground = "\${colors.foreground-alt}";
+        format-full-underline = "\${self.format-charging-underline}";
+
+        ramp-capacity-0 = "";
+        ramp-capacity-1 = "";
+        ramp-capacity-2 = "";
+        ramp-capacity-foreground = "\${colors.foreground-alt}";
+
+        animation-charging-0 = "";
+        animation-charging-1 = "";
+        animation-charging-2 = "";
+        animation-charging-foreground = "\${colors.foreground-alt}";
+        animation-charging-framerate = 750;
+
+        animation-discharging-0 = "";
+        animation-discharging-1 = "";
+        animation-discharging-2 = "";
+        animation-discharging-foreground = "\${colors.foreground-alt}";
+        animation-discharging-framerate = 750;
+      };
+
+      "module/temperature" = {
+        type = "internal/temperature";
+        warn-temperature = 60;
+        hwmon-path = "/sys/devices/pci0000:00/0000:00:18.3/hwmon/hwmon1/temp2_input";
+
+        format = "<ramp> <label>";
+        format-warn = "<ramp> <label-warn>";
+
+        label = "cpu %temperature-c%";
+        label-warn = "cpu %temperature-c%";
+        label-warn-foreground = "\${colors.secondary}";
+
+        ramp-0 = "";
+        ramp-1 = "";
+        ramp-2 = "";
+        ramp-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/gputemperature" = {
+        type = "internal/temperature";
+        warn-temperature = 60;
+        hwmon-path = "/sys/devices/pci0000:00/0000:00:03.1/0000:09:00.0/hwmon/hwmon3/temp1_input";
+
+        format = "<ramp> <label>";
+        format-warn = "<ramp> <label-warn>";
+
+        label = "gpu %temperature-c%";
+        label-warn = "gpu %temperature-c%";
+        label-warn-foreground = "\${colors.secondary}";
+
+        ramp-0 = "";
+        ramp-1 = "";
+        ramp-2 = "";
+        ramp-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/nvmetemperature" = {
+        type = "internal/temperature";
+        warn-temperature = 60;
+        hwmon-path = "/sys/devices/pci0000:00/0000:00:01.1/0000:01:00.0/hwmon/hwmon0/temp1_input";
+
+        format = "<ramp> <label>";
+        format-warn = "<ramp> <label-warn>";
+
+        label = "M.2 %temperature-c%";
+        label-warn = "M.2 %temperature-c%";
+        label-warn-foreground = "\${colors.secondary}";
+
+        ramp-0 = "";
+        ramp-1 = "";
+        ramp-2 = "";
+        ramp-foreground = "\${colors.foreground-alt}";
+      };
+
+      "module/powermenu" = {
+        type = "custom/menu";
+
+        expand-right = true;
+
+        format-spacing = 1;
+
+        label-open = "";
+        label-open-foreground = "\${colors.secondary}";
+        label-close = " cancel";
+        label-close-foreground = "\${colors.secondary}";
+        label-separator = "|";
+        label-separator-foreground = "\${colors.foreground-alt}";
+
+        menu-0-0 = "reboot";
+        menu-0-0-exec = "menu-open-1";
+        menu-0-1 = "power off";
+        menu-0-1-exec = "menu-open-2";
+
+        menu-1-0 = "cancel";
+        menu-1-0-exec = "menu-open-0";
+        menu-1-1 = "reboot";
+        menu-1-1-exec = "sudo reboot";
+
+        menu-2-0 = "power off";
+        menu-2-0-exec = "sudo poweroff";
+        menu-2-1 = "cancel";
+        menu-2-1-exec = "menu-open-0";
+      };
+
+      "module/sink_changer" = {
+        type = "custom/script";
+        exec = "/home/fabian/bin/polybar_scripts/info.sh";
+        label = "%output%";
+        click-left = "/home/fabian/bin/polybar_scripts/sink_changer.sh";
+        # format-prefix = " ";
+        interval = "0";
+        # format-prefix-foreground = "${colors.foreground-alt}";
+      };
+
+      "settings" = {
+        screenchange-reload = true;
+        # compositing-background = "xor";
+        # compositing-background = "screen";
+        # compositing-foreground = "source";
+        # compositing-border = "over";
+        # pseudo-transparency = false;
+      };
+
+      "global/wm" = {
+        margin-top = 5;
+        margin-bottom = 5;
+      };
+    };
+  };
+}

home/modules/gui/startx.nix

@@ -0,0 +1,16 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; {
+  config = mkIf config.local.gui.enable {
+    home.file.".xinitrc".source = let
+      content = ''
+        exec ~/.xsession
+      '';
+    in
+      pkgs.writeShellScript "xinitrc" content;
+  };
+}