{
  fetchgit,
  lib,
  makeWrapper,
  maven,
  openjdk,
  wrapGAppsHook3,
  libasep11 ? null,
}: let
  jdk = openjdk.override {
    enableJavaFX = true;
  };

  version = "1.9.8+master";
in
  maven.buildMavenPackage {
    pname = "firmador";
    inherit version;

    src = fetchgit {
      url = "https://codeberg.org/firmador/firmador";
      rev = "676b0e3c0dc5adb0628d4d98efcfccfca3daa8a7";
      hash = "sha256-f/EKll1csvUCRSt4G1SeDB4gVW+ZtUgJjlmM7PlafyQ=";
    };

    patches = [
      ./0001-Remove-CheckUpdatePlugin-from-default-list.patch
    ];

    mvnHash = "sha256-0vwJ1f+0UXxrXRaJ1BHqfOXDU/pxrSPdYYEQ71m4jJQ=";

    nativeBuildInputs = [
      makeWrapper
      wrapGAppsHook3
    ];

    postPatch = lib.optionalString (libasep11 != null) ''
      sed -i 's@/usr/lib/x64-athena/libASEP11.so@${libasep11}@g' src/main/java/cr/libre/firmador/signers/CRSigner.java
    '';

    installPhase = ''
      runHook preInstall

      mkdir -p $out/bin $out/share/java
      install -Dm644 target/firmador.jar $out/share/java

      makeWrapper ${jdk}/bin/java $out/bin/firmador \
        --add-flags "-jar $out/share/java/firmador.jar"

      runHook postInstall
    '';

    meta = {
      homepage = "https://firmador.libre.cr";
      license = lib.licenses.gpl3Plus;
    };
  }