diff --git a/.gitignore b/.gitignore
index 21f979d..f094862 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1,3 +1,2 @@
 !**/.keep
 result
-flake.lock
diff --git a/README.md b/README.md
new file mode 100644
index 0000000..aced5a2
--- /dev/null
+++ b/README.md
@@ -0,0 +1,8 @@
+### Push:
+
+    git subtree push --prefix=trivionomicon forgejo@git.posixlycorrect.com:deepState/trivionomicon.git master
+
+
+### Pull:
+
+    git subtree pull --prefix=trivionomicon forgejo@git.posixlycorrect.com:deepState/trivionomicon.git master
diff --git a/doctrine/default.nix b/doctrine/default.nix
new file mode 100644
index 0000000..0d50d49
--- /dev/null
+++ b/doctrine/default.nix
@@ -0,0 +1,16 @@
+{
+  lib ? pkgs.lib,
+  pkgs,
+  prefix ? "trivium",
+  namespace ? null,
+}: let
+  doctrine =
+    {
+      lib = import ./lib {inherit lib pkgs doctrine;};
+      inherit namespace prefix;
+    }
+    // lib.optionalAttrs (pkgs != null) {
+      inherit pkgs;
+    };
+in
+  doctrine
diff --git a/doctrine/lib/default.nix b/doctrine/lib/default.nix
new file mode 100644
index 0000000..e2d84b8
--- /dev/null
+++ b/doctrine/lib/default.nix
@@ -0,0 +1,23 @@
+{
+  lib,
+  doctrine,
+  pkgs,
+}: let
+  close = vars: f: args:
+    (
+      if builtins.isPath f
+      then import f
+      else f
+    )
+    (args // vars);
+
+  closeLib = close {inherit lib;};
+  closeFull = close {inherit lib pkgs doctrine;};
+in
+  {
+    inherit close;
+    importAll = closeLib ./import-all.nix;
+  }
+  // lib.optionalAttrs (doctrine.namespace != null) {
+    mkModule = closeFull ./mk-module.nix;
+  }
diff --git a/pkgs/lib/importAll.nix b/doctrine/lib/import-all.nix
similarity index 83%
rename from pkgs/lib/importAll.nix
rename to doctrine/lib/import-all.nix
index 6acabe9..423dd9c 100644
--- a/pkgs/lib/importAll.nix
+++ b/doctrine/lib/import-all.nix
@@ -1,6 +1,7 @@
-{lib}: {
+{
+  lib,
   root,
-  exclude ? [],
+  exclude ? ["default"],
 }:
 with builtins;
 with lib;
@@ -10,7 +11,7 @@ with lib;
 
     isMatch = name: type:
       (hasSuffix ".nix" name || type == "directory")
-      && ! elem name (map basename exclude);
+      && ! elem (basename name) exclude;
 
     entry = name: _: {
       name = basename name;
diff --git a/doctrine/lib/mk-module.nix b/doctrine/lib/mk-module.nix
new file mode 100644
index 0000000..ffbe6bc
--- /dev/null
+++ b/doctrine/lib/mk-module.nix
@@ -0,0 +1,51 @@
+{
+  # The first few arguments are implicitly passed by the 'close' helper
+  lib,
+  pkgs,
+  doctrine,
+  name,
+  config,
+  hm ? null,
+  sys ? null,
+  options ? null,
+  requires ? [],
+  prefix ? doctrine.prefix,
+  namespace ? doctrine.namespace,
+  passthru ? {},
+}: let
+  optionsSet = import options (passthru
+    // {
+      inherit config lib pkgs cfg name doctrine;
+    });
+
+  configSet = import configFiles.${namespace} (passthru
+    // {
+      inherit config lib pkgs doctrine cfg;
+    });
+
+  configFiles = lib.filterAttrs (k: v: v != null) {
+    inherit sys hm;
+  };
+
+  cfg = config.${prefix}.${name};
+in {
+  config =
+    lib.optionalAttrs (configFiles ? ${namespace})
+    (lib.mkIf cfg.enable (lib.mkMerge [
+      configSet
+      {
+        assertions =
+          map (dependency: {
+            assertion = cfg.enable -> config.${prefix}.${dependency}.enable;
+            message = "${prefix}.${name}.enable requires ${prefix}.${dependency}.enable";
+          })
+          requires;
+      }
+    ]));
+
+  options.${prefix}.${name} =
+    lib.optionalAttrs (options != null && optionsSet ? ${namespace}) optionsSet.${namespace}
+    // {
+      enable = lib.mkEnableOption name;
+    };
+}
diff --git a/flake.lock b/flake.lock
new file mode 100644
index 0000000..8730827
--- /dev/null
+++ b/flake.lock
@@ -0,0 +1,61 @@
+{
+  "nodes": {
+    "flake-utils": {
+      "inputs": {
+        "systems": "systems"
+      },
+      "locked": {
+        "lastModified": 1731533236,
+        "narHash": "sha256-l0KFg5HjrsfsO/JpG+r7fRrqm12kzFHyUHqHCVpMMbI=",
+        "owner": "numtide",
+        "repo": "flake-utils",
+        "rev": "11707dc2f618dd54ca8739b309ec4fc024de578b",
+        "type": "github"
+      },
+      "original": {
+        "owner": "numtide",
+        "repo": "flake-utils",
+        "type": "github"
+      }
+    },
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1754292888,
+        "narHash": "sha256-1ziydHSiDuSnaiPzCQh1mRFBsM2d2yRX9I+5OPGEmIE=",
+        "owner": "nixos",
+        "repo": "nixpkgs",
+        "rev": "ce01daebf8489ba97bd1609d185ea276efdeb121",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nixos",
+        "ref": "nixos-25.05",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "flake-utils": "flake-utils",
+        "nixpkgs": "nixpkgs"
+      }
+    },
+    "systems": {
+      "locked": {
+        "lastModified": 1681028828,
+        "narHash": "sha256-Vy1rq5AaRuLzOxct8nz4T6wlgyUR7zLU309k9mBC768=",
+        "owner": "nix-systems",
+        "repo": "default",
+        "rev": "da67096a3b9bf56a91d16901293e51ba5b49a27e",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nix-systems",
+        "repo": "default",
+        "type": "github"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}
diff --git a/flake.nix b/flake.nix
index d8e51c6..2b53ebd 100644
--- a/flake.nix
+++ b/flake.nix
@@ -1,21 +1,39 @@
 {
-  inputs.flake-utils.url = "github:numtide/flake-utils";
+  inputs = {
+    flake-utils.url = "github:numtide/flake-utils";
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.05";
+  };
 
   outputs = {
     self,
     nixpkgs,
     flake-utils,
   }: let
-    mapOverlayOverride = namespace: overlay: final: prev: let
+    mapOverlayOverride = prefix: overlay: final: prev: let
       overlayPkgs = overlay final prev;
     in
       {
-        "${namespace}" = builtins.removeAttrs overlayPkgs ["override"];
+        "${prefix}" = (prev.${prefix} or {}) // builtins.removeAttrs overlayPkgs ["override"];
       }
       // (overlayPkgs.override or {});
+
+    doctrineNoPkgs = self.lib.mkDoctrine {
+      lib = nixpkgs.lib;
+      pkgs = null;
+    };
   in
-    flake-utils.lib.eachDefaultSystem (system: {
-      formatter = (import nixpkgs {inherit system;}).alejandra;
+    flake-utils.lib.eachDefaultSystem (system: let
+      pkgs = import nixpkgs {inherit system;};
+    in {
+      formatter = pkgs.alejandra;
+
+      packages =
+        (import nixpkgs {
+          inherit system;
+          overlays = [self.overlays.default];
+        }).${
+          doctrineNoPkgs.prefix
+        };
     })
     // {
       templates = let
@@ -30,30 +48,37 @@
       };
 
       overlays = let
-        overlay = mapOverlayOverride "trivium" (import ./pkgs);
+        overlay = mapOverlayOverride doctrineNoPkgs.prefix (import ./pkgs);
       in {
         default = overlay;
-        trivium = overlay;
+        ${doctrineNoPkgs.prefix} = overlay;
       };
 
+      homeManagerModules.default = ./modules;
+      nixosModules.default = ./modules;
+
       lib = {
+        mkDoctrine = import ./doctrine;
+
         mkSystemFlake = {
           flakes,
           system,
+          doctrinePrefix ? null,
           formatter ? "alejandra",
-          localOverlayPath ? /. + "${flakes.self}" + /pkgs,
-          nixpkgsConfigPath ? localOverlayPath + /config,
-          nixosSourcePath ? /. + "${flakes.self}" + /sys,
-          nixosPlatformsPath ?
-            if nixosSourcePath != null
-            then nixosSourcePath + /platform
-            else null,
-          hmSourcePath ? /. + "${flakes.self}" + /home,
-          hmPlatformsPath ?
-            if hmSourcePath != null
-            then hmSourcePath + /platform
-            else null,
+          paths ? {},
         }: let
+          mkDoctrine = args:
+            self.lib.mkDoctrine
+            (args
+              // optionalAttrs (doctrinePrefix != null) {
+                prefix = doctrinePrefix;
+              });
+
+          doctrineNoPkgs = mkDoctrine {
+            lib = nixpkgs.lib;
+            pkgs = null;
+          };
+
           optionalFlake = name:
             if flakes ? "${name}"
             then flakes.${name}
@@ -62,7 +87,7 @@
           requireFlake = name:
             if flakes ? "${name}"
             then flakes.${name}
-            else throw "Required flake input '${name}' is required but was not provided";
+            else throw "Required flake input '${name}' is missing";
 
           nur = optionalFlake "nur";
           nixpkgs = requireFlake "nixpkgs";
@@ -73,13 +98,21 @@
             then requireFlake "home-manager"
             else null;
 
+          pathFromSelf = path: builtins.toPath "${flakes.self}" + "/${path}";
+
+          localOverlayPath = pathFromSelf paths.localOverlay;
+          nixpkgsConfigPath = pathFromSelf paths.nixpkgsConfig;
+          nixosSourcePath = pathFromSelf paths.nixosSource;
+          nixosPlatformsPath = pathFromSelf paths.nixosPlatforms;
+          hmSourcePath = pathFromSelf paths.hmSource;
+          hmPlatformsPath = pathFromSelf paths.hmPlatforms;
+
           pkgs = importPkgs nixpkgs;
 
           importPkgs = flake:
             import flake ({
                 inherit system;
 
-                config = import ./pkgs/config nixpkgs.lib;
                 overlays = let
                   conditions = [
                     {
@@ -88,7 +121,7 @@
                     }
                     # NB: Preserve the relative order
                     {
-                      overlay = self.overlays.trivium;
+                      overlay = mapOverlayOverride prefix (import ./pkgs);
                       condition = true;
                     }
                     {
@@ -99,87 +132,98 @@
                 in
                   builtins.map (cond: cond.overlay) (builtins.filter (cond: cond.condition) conditions);
               }
-              // (
-                if nixpkgsConfigPath != null
-                then {
-                  config = import nixpkgsConfigPath {inherit (nixpkgs) lib;};
-                }
-                else {}
-              ));
+              // optionalAttrs (paths ? nixpkgsConfig) {
+                config = import nixpkgsConfigPath {inherit (nixpkgs) lib;};
+              });
 
-          inherit (pkgs.trivium.lib) importAll;
+          inherit (pkgs) lib;
+          inherit (nixpkgs.lib) optionalAttrs; # Prevents infinite recursion
+          inherit (doctrineNoPkgs) prefix;
+          inherit (doctrineNoPkgs.lib) importAll;
         in
-          with pkgs.lib;
-            {
-              formatter.${system} =
-                if formatter == "alejandra"
-                then pkgs.alejandra
-                else if formatter == "nixpkgs-fmt"
-                then pkgs.nixpkgs-fmt
-                else throw "Unknown formatter: '${formatter}'";
+          {
+            formatter.${system} =
+              if formatter == "alejandra"
+              then pkgs.alejandra
+              else if formatter == "nixpkgs-fmt"
+              then pkgs.nixpkgs-fmt
+              else throw "Unknown formatter: '${formatter}'";
 
-              packages.${system} = pkgs.local;
+            packages.${system} = pkgs.${prefix};
 
-              overlays.default = final: prev: let
-                overlay =
-                  if localOverlayPath != null
-                  then import localOverlayPath
-                  else (final: prev: {});
-              in
-                mapOverlayOverride "local" overlay final prev
-                // optionalAttrs (unstable != null) {
-                  unstable = importPkgs unstable;
+            overlays.default = final: prev: let
+              overlay = final: prev:
+                if paths ? localOverlay
+                then import localOverlayPath {inherit final prev flakes;}
+                else {};
+            in
+              mapOverlayOverride prefix overlay final prev
+              // optionalAttrs (unstable != null) {
+                unstable = importPkgs unstable;
+              };
+          }
+          // optionalAttrs (paths ? nixosSource) {
+            nixosConfigurations = let
+              hostConfig = platform:
+                self.lib.mkSystem {
+                  inherit flakes pkgs;
+                  doctrine = doctrineNoPkgs;
+
+                  modules = [
+                    nixosSourcePath
+                    platform
+                  ];
                 };
-            }
-            // optionalAttrs (nixosSourcePath != null) {
-              nixosConfigurations = let
-                nixosSystem = {modules}:
-                  makeOverridable nixpkgs.lib.nixosSystem {
-                    inherit modules pkgs system;
+            in
+              lib.mapAttrs (_: hostConfig) (importAll {root = nixosPlatformsPath;});
+          }
+          // optionalAttrs (paths ? hmSource) {
+            homeConfigurations = let
+              home = name: platform:
+                home-manager.lib.homeManagerConfiguration {
+                  inherit pkgs;
 
-                    specialArgs = {
-                      inherit flakes;
+                  extraSpecialArgs = {
+                    inherit flakes;
+
+                    doctrine = mkDoctrine {
+                      inherit pkgs;
+                      namespace = "hm";
                     };
                   };
 
-                hostConfig = platform:
-                  nixosSystem {
-                    modules = [
-                      ./nixos
-                      nixosSourcePath
-                      platform
-                    ];
-                  };
-              in
-                mapAttrs (_: hostConfig) (importAll {root = nixosPlatformsPath;});
-            }
-            // optionalAttrs (hmSourcePath != null) {
-              homeConfigurations = let
-                registry = {...}: {
-                  config.nix.registry =
-                    mapAttrs
-                    (_: value: {flake = value;})
-                    flakes;
+                  modules = [
+                    self.homeManagerModules.default
+                    hmSourcePath
+                    platform
+                  ];
                 };
+            in
+              lib.mapAttrs home (importAll {root = hmPlatformsPath;});
+          };
 
-                home = name: platform:
-                  home-manager.lib.homeManagerConfiguration {
-                    inherit pkgs;
+        mkSystem = {
+          pkgs,
+          flakes,
+          doctrine,
+          modules,
+        }:
+          flakes.nixpkgs.lib.makeOverridable flakes.nixpkgs.lib.nixosSystem {
+            inherit pkgs;
+            inherit (pkgs) system;
 
-                    extraSpecialArgs = {
-                      inherit flakes;
-                    };
+            modules = [self.nixosModules.default] ++ modules;
 
-                    modules = [
-                      ./hm
-                      hmSourcePath
-                      platform
-                      registry
-                    ];
-                  };
-              in
-                mapAttrs home (importAll {root = hmPlatformsPath;});
+            specialArgs = {
+              inherit flakes;
+
+              doctrine = self.lib.mkDoctrine {
+                inherit pkgs;
+                inherit (doctrine) prefix;
+                namespace = "sys";
+              };
             };
+          };
       };
     };
 }
diff --git a/hm/default.nix b/hm/default.nix
deleted file mode 100644
index 0967ef4..0000000
--- a/hm/default.nix
+++ /dev/null
@@ -1 +0,0 @@
-{}
diff --git a/modules/athena-bccr/default.nix b/modules/athena-bccr/default.nix
new file mode 100644
index 0000000..93c5660
--- /dev/null
+++ b/modules/athena-bccr/default.nix
@@ -0,0 +1,14 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "athena-bccr";
+  hm = ./hm.nix;
+  sys = ./sys.nix;
+  options = ./options.nix;
+}
diff --git a/modules/athena-bccr/hm.nix b/modules/athena-bccr/hm.nix
new file mode 100644
index 0000000..0678e3c
--- /dev/null
+++ b/modules/athena-bccr/hm.nix
@@ -0,0 +1,14 @@
+{
+  pkgs,
+  lib,
+  cfg,
+  doctrine,
+  ...
+}: let
+  athena = pkgs.${doctrine.prefix}.athena-bccr.${cfg.release};
+in {
+  home.packages = [
+    athena.firmador
+    (athena.gaudi.override {inherit (cfg) gaudiHash;})
+  ];
+}
diff --git a/modules/athena-bccr/options.nix b/modules/athena-bccr/options.nix
new file mode 100644
index 0000000..eb61cf5
--- /dev/null
+++ b/modules/athena-bccr/options.nix
@@ -0,0 +1,30 @@
+{lib, ...}:
+with lib.types; {
+  hm = {
+    gaudiHash = lib.mkOption {
+      type = nullOr str;
+      default = null;
+      description = "hash of the Gaudi client";
+    };
+
+    release = lib.mkOption {
+      type = str;
+      default = "latest";
+      description = "pinned athena-bccr release tag";
+    };
+  };
+
+  sys = {
+    group = lib.mkOption {
+      type = str;
+      default = "users";
+      description = "user group with full access to the smartcard reader";
+    };
+
+    release = lib.mkOption {
+      type = str;
+      default = "latest";
+      description = "pinned athena-bccr release tag";
+    };
+  };
+}
diff --git a/modules/athena-bccr/sys.nix b/modules/athena-bccr/sys.nix
new file mode 100644
index 0000000..631185d
--- /dev/null
+++ b/modules/athena-bccr/sys.nix
@@ -0,0 +1,35 @@
+{
+  pkgs,
+  lib,
+  cfg,
+  doctrine,
+  ...
+}: let
+  athena = pkgs.${doctrine.prefix}.athena-bccr.${cfg.release};
+in {
+  environment = {
+    etc = {
+      "Athena".source = "${athena.ase-pkcs11}/etc/Athena";
+
+      "pkcs11/modules/asep11".text = ''
+        module: ${athena.libasep11}
+      '';
+    };
+
+    systemPackages = [athena.ase-pkcs11];
+  };
+
+  #FIXME: Extremadamente peligroso si BCCR o MICITT caen, investigar política nacional de root CA
+  security.pki.certificateFiles = ["${athena.bccr-cacerts}/root-ca.pem"];
+
+  services = {
+    pcscd.enable = true;
+
+    udev.extraRules = ''
+      # Athena Smartcard Solutions, Inc. ASEDrive V3CR
+      ATTRS{idVendor}=="0dc3", ATTRS{idProduct}=="1004", MODE="660", GROUP="${cfg.group}", TAG+="uaccess"
+    '';
+  };
+
+  users.groups.${cfg.group} = {};
+}
diff --git a/modules/default.nix b/modules/default.nix
new file mode 100644
index 0000000..0c0fd4c
--- /dev/null
+++ b/modules/default.nix
@@ -0,0 +1,3 @@
+{doctrine, ...}: {
+  imports = builtins.attrValues (doctrine.lib.importAll {root = ./.;});
+}
diff --git a/modules/laptop/default.nix b/modules/laptop/default.nix
new file mode 100644
index 0000000..b908d47
--- /dev/null
+++ b/modules/laptop/default.nix
@@ -0,0 +1,10 @@
+{
+  config,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "laptop";
+  sys = ./sys.nix;
+}
diff --git a/modules/laptop/sys.nix b/modules/laptop/sys.nix
new file mode 100644
index 0000000..252f49c
--- /dev/null
+++ b/modules/laptop/sys.nix
@@ -0,0 +1,11 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  services = {
+    tlp.enable = lib.mkDefault true;
+    upower.enable = lib.mkDefault true;
+  };
+}
diff --git a/modules/nix-registry/default.nix b/modules/nix-registry/default.nix
new file mode 100644
index 0000000..8406d88
--- /dev/null
+++ b/modules/nix-registry/default.nix
@@ -0,0 +1,16 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  flakes,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "nix-registry";
+  hm = ./hm.nix;
+  options = ./options.nix;
+
+  passthru = {inherit flakes;};
+}
diff --git a/modules/nix-registry/hm.nix b/modules/nix-registry/hm.nix
new file mode 100644
index 0000000..1c57e95
--- /dev/null
+++ b/modules/nix-registry/hm.nix
@@ -0,0 +1,23 @@
+{
+  pkgs,
+  lib,
+  cfg,
+  flakes,
+  ...
+}: let
+  registryName = name:
+    if name == "self"
+    then cfg.renameSelf
+    else name;
+
+  registryFilter = {
+    nixpkgs = true;
+    unstable = true;
+    self = cfg.renameSelf != null;
+  };
+in {
+  nix.registry =
+    lib.mapAttrs'
+    (name: value: lib.nameValuePair (registryName name) {flake = value;})
+    (lib.filterAttrs (name: _: registryFilter.${name} or cfg.allInputs) flakes);
+}
diff --git a/modules/nix-registry/options.nix b/modules/nix-registry/options.nix
new file mode 100644
index 0000000..e8898ec
--- /dev/null
+++ b/modules/nix-registry/options.nix
@@ -0,0 +1,19 @@
+{lib, ...}:
+with lib.types; {
+  hm = {
+    allInputs = mkOption {
+      type = bool;
+      default = default;
+      description = ''
+        Include all flake inputs. If false, only 'nixpkgs' and 'unstable'
+        (if available) will be added to the flake registry by default.
+      '';
+    };
+
+    renameSelf = mkOption {
+      type = nullOr str;
+      default = "self";
+      description = "Registry name to use for the 'self' input";
+    };
+  };
+}
diff --git a/modules/soju/default.nix b/modules/soju/default.nix
new file mode 100644
index 0000000..2b302f0
--- /dev/null
+++ b/modules/soju/default.nix
@@ -0,0 +1,13 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "soju";
+  sys = ./sys.nix;
+  options = ./options.nix;
+}
diff --git a/modules/soju/options.nix b/modules/soju/options.nix
new file mode 100644
index 0000000..06c3381
--- /dev/null
+++ b/modules/soju/options.nix
@@ -0,0 +1,16 @@
+{lib, ...}:
+with lib.types; {
+  sys = {
+    fullyQualifiedDomain = lib.mkOption {
+      type = str;
+      example = "soju.trivionomicon.com";
+      description = "fully qualified domain name to be used by soju";
+    };
+
+    port = lib.mkOption {
+      type = port;
+      default = 6697;
+      description = "port to be used by soju";
+    };
+  };
+}
diff --git a/modules/soju/sys.nix b/modules/soju/sys.nix
new file mode 100644
index 0000000..83c3560
--- /dev/null
+++ b/modules/soju/sys.nix
@@ -0,0 +1,47 @@
+{
+  config,
+  pkgs,
+  lib,
+  cfg,
+  doctrine,
+  ...
+}:
+with lib; {
+  security.acme.certs."${cfg.fullyQualifiedDomain}" = {
+    reloadServices = ["soju.service"];
+    group = "soju";
+  };
+
+  networking.firewall.allowedTCPPorts = [cfg.port];
+
+  services.soju = let
+    sojuCertDir = config.security.acme.certs."${cfg.fullyQualifiedDomain}".directory;
+  in {
+    enable = true;
+    hostName = "${cfg.fullyQualifiedDomain}";
+    listen = ["ircs://[::]:${toString cfg.port}"];
+    tlsCertificate = "${sojuCertDir}/fullchain.pem";
+    tlsCertificateKey = "${sojuCertDir}/key.pem";
+  };
+
+  systemd.services.soju = {
+    after = ["acme-${cfg.fullyQualifiedDomain}.service"];
+    serviceConfig = {
+      DynamicUser = mkForce false; # fuck dynamic users
+      User = "soju";
+      Group = "soju";
+      ProtectSystem = "strict";
+      ProtectHome = "read-only";
+      PrivateTmp = true;
+      RemoveIPC = true;
+    };
+  };
+
+  users = {
+    users.soju = {
+      isSystemUser = true;
+      group = "soju";
+    };
+    groups.soju = {};
+  };
+}
diff --git a/modules/sway/default.nix b/modules/sway/default.nix
new file mode 100644
index 0000000..9f49e7c
--- /dev/null
+++ b/modules/sway/default.nix
@@ -0,0 +1,13 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "sway";
+  sys = ./sys.nix;
+  options = ./options.nix;
+}
diff --git a/modules/sway/options.nix b/modules/sway/options.nix
new file mode 100644
index 0000000..e433039
--- /dev/null
+++ b/modules/sway/options.nix
@@ -0,0 +1,3 @@
+{...}: {
+  sys = {};
+}
diff --git a/modules/sway/sys.nix b/modules/sway/sys.nix
new file mode 100644
index 0000000..9c8b664
--- /dev/null
+++ b/modules/sway/sys.nix
@@ -0,0 +1,45 @@
+{
+  pkgs,
+  lib,
+  ...
+}: {
+  services.libinput.enable = true;
+  hardware.graphics.enable = true;
+
+  xdg.portal = {
+    enable = true;
+    wlr.enable = true;
+    extraPortals = with pkgs; [xdg-desktop-portal-gtk];
+    xdgOpenUsePortal = true;
+
+    # warning: xdg-desktop-portal 1.17 reworked how portal implementations are loaded, you
+    # should either set `xdg.portal.config` or `xdg.portal.configPackages`
+    # to specify which portal backend to use for the requested interface.
+    #
+    # https://github.com/flatpak/xdg-desktop-portal/blob/1.18.1/doc/portals.conf.rst.in
+    #
+    # If you simply want to keep the behaviour in < 1.17, which uses the first
+    # portal implementation found in lexicographical order, use the following:
+    #
+    # xdg.portal.config.common.default = "*";
+    config.common.default = "*";
+  };
+
+  environment = {
+    sessionVariables.NIXOS_OZONE_WL = "1";
+
+    systemPackages = with pkgs; [
+      qt5.qtwayland
+      qt6.qtwayland
+    ];
+  };
+
+  programs = {
+    gtklock = {
+      enable = lib.mkDefault true;
+
+      config = {};
+      modules = [];
+    };
+  };
+}
diff --git a/modules/thinkpad/default.nix b/modules/thinkpad/default.nix
new file mode 100644
index 0000000..e210947
--- /dev/null
+++ b/modules/thinkpad/default.nix
@@ -0,0 +1,11 @@
+{
+  config,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "thinkpad";
+  sys = ./sys.nix;
+  requires = ["laptop"];
+}
diff --git a/modules/thinkpad/sys.nix b/modules/thinkpad/sys.nix
new file mode 100644
index 0000000..bc96146
--- /dev/null
+++ b/modules/thinkpad/sys.nix
@@ -0,0 +1,30 @@
+{
+  config,
+  pkgs,
+  lib,
+  ...
+}: {
+  # For suspending to RAM to work, set Config -> Power -> Sleep State to "Linux" in EFI.
+  # See https://wiki.archlinux.org/index.php/Lenovo_ThinkPad_X1_Carbon_(Gen_6)#Suspend_issues
+  # Fingerprint sensor requires a firmware-update to work.
+
+  boot = {
+    extraModulePackages = with config.boot.kernelPackages; [acpi_call];
+    extraModprobeConfig = "options iwlwifi 11n_disable=1 wd_disable=1";
+
+    # acpi_call makes tlp work for newer thinkpads
+    kernelModules = ["acpi_call"];
+
+    # Force use of the thinkpad_acpi driver for backlight control.
+    # This allows the backlight save/load systemd service to work.
+    kernelParams = ["acpi_backlight=native"];
+  };
+
+  hardware.firmware = [pkgs.sof-firmware];
+
+  services = {
+    fprintd.enable = lib.mkDefault true;
+    thinkfan.enable = lib.mkDefault true;
+    tp-auto-kbbl.enable = lib.mkDefault true;
+  };
+}
diff --git a/modules/trivionomiconMotd/default.nix b/modules/trivionomiconMotd/default.nix
new file mode 100644
index 0000000..0844b5a
--- /dev/null
+++ b/modules/trivionomiconMotd/default.nix
@@ -0,0 +1,10 @@
+{
+  config,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "trivionomiconMotd";
+  sys = ./sys.nix;
+}
diff --git a/modules/trivionomiconMotd/sys.nix b/modules/trivionomiconMotd/sys.nix
new file mode 100644
index 0000000..5b38e3d
--- /dev/null
+++ b/modules/trivionomiconMotd/sys.nix
@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  users.motd = ''
+                                          _   _             _   _
+                                         | | | |           | | | |
+     _ __   _____      _____ _ __ ___  __| | | |__  _   _  | |_| |__   ___
+    | '_ \ / _ \ \ /\ / / _ \ '__/ _ \/ _` | | '_ \| | | | | __| '_ \ / _ \
+    | |_) | (_) \ V  V /  __/ | |  __/ (_| | | |_) | |_| | | |_| | | |  __/
+    | .__/ \___/ \_/\_/ \___|_|  \___|\__,_| |_.__/ \__, |  \__|_| |_|\___|
+    | |                                              __/ |
+    |_|_____ _____  _______      _______ ____  _   _|___/_  __  __ _____ _____ ____  _   _
+    |__   __|  __ \|_   _\ \    / /_   _/ __ \| \ | |/ __ \|  \/  |_   _/ ____/ __ \| \ | |
+       | |  | |__) | | |  \ \  / /  | || |  | |  \| | |  | | \  / | | || |   | |  | |  \| |
+       | |  |  _  /  | |   \ \/ /   | || |  | | . ` | |  | | |\/| | | || |   | |  | | . ` |
+       | |  | | \ \ _| |_   \  /   _| || |__| | |\  | |__| | |  | |_| || |___| |__| | |\  |
+       |_|  |_|  \_\_____|   \/   |_____\____/|_| \_|\____/|_|  |_|_____\_____\____/|_| \_|
+  '';
+}
diff --git a/modules/waybar/default.nix b/modules/waybar/default.nix
new file mode 100644
index 0000000..97cacf3
--- /dev/null
+++ b/modules/waybar/default.nix
@@ -0,0 +1,13 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "waybar";
+  hm = ./hm.nix;
+  options = ./options.nix;
+}
diff --git a/modules/waybar/hm.nix b/modules/waybar/hm.nix
new file mode 100644
index 0000000..1bfa3e2
--- /dev/null
+++ b/modules/waybar/hm.nix
@@ -0,0 +1,207 @@
+{
+  lib,
+  pkgs,
+  cfg,
+  doctrine,
+  ...
+}:
+with lib; {
+  programs.waybar = {
+    enable = true;
+    settings = {
+      mainBar = {
+        layer = "top";
+        position = "top";
+        height = 20;
+        spacing = 0;
+
+        modules-left = [
+          "sway/workspaces"
+          "sway/mode"
+        ];
+        modules-center = [
+          "clock"
+        ];
+
+        modules-right =
+          [
+            "keyboard-state"
+            "privacy"
+            "idle_inhibitor"
+            "cpu"
+            "memory"
+            "disk"
+            "temperature"
+            "tray"
+          ]
+          ++ lists.optionals cfg.battery [
+            "battery"
+          ];
+        battery = mkIf cfg.battery {
+          format = "{capacity}% {icon}";
+          format-plugged = "{capacity}% 󱐥{icon}";
+          format-icons = ["󰂃" "󰁺" "󰁻" "󰁼" "󰁽" "󰁾" "󰁿" "󰂀" "󰂁" "󰂂" "󰁹"];
+          states = {
+            warning = 20;
+            critical = 10;
+          };
+        };
+        keyboard-state = {
+          capslock = true;
+          format.capslock = "{icon}";
+          format-icons = {
+            locked = "󰘲 ";
+            unlocked = "";
+          };
+        };
+        idle_inhibitor = {
+          format = "{icon}";
+          format-icons = {
+            activated = " ";
+            deactivated = " ";
+          };
+        };
+        tray = {
+          icon-size = 13;
+          spacing = 8;
+        };
+        clock = {
+          interval = 60;
+          format = "{:%A %B %d %Y %H:%M}";
+          tooltip = false;
+        };
+        cpu = {
+          format = " {usage}%";
+          tooltip = false;
+        };
+        memory = {
+          format = " {percentage}% ";
+          tooltip = true;
+          tooltip-format = "{used}/{total}";
+        };
+        disk = {
+          format = " {specific_used:0.0f}/{specific_total:0.0f}";
+          unit = "GiB";
+          tooltip = false;
+        };
+        temperature = {
+          format = " {temperatureC}°C";
+        };
+        privacy = {
+          icon-size = 12;
+        };
+      };
+    };
+    style = ''
+      * {
+        font-family: "${cfg.fontFamily}", monospace;
+        font-size: ${cfg.fontSize};
+        font-weight: 500;
+        border: none;
+        box-shadow: none;
+      }
+
+      /* Entire bar: fully transparent, no border */
+      window#waybar {
+        background: transparent;
+        color: #eaeaea;
+        margin: 0;
+        padding: 0;
+      }
+
+      /* Optional: small edge breathing room (comment out if you want edge-to-edge) */
+      /* window#waybar { margin: 3px 6px 0 6px; } */
+
+      /* Module containers */
+      .modules-left, .modules-center, .modules-right {
+        padding: 0;
+        margin: 0 6px;
+      }
+
+      /* Subtle separators between modules (no boxes) */
+      .modules-left > widget:not(:first-child),
+      .modules-center > widget:not(:first-child),
+      .modules-right > widget:not(:first-child) {
+        margin-left: 12px;
+        padding-left: 12px;
+        border-left: 1px solid rgba(255, 255, 255, 0.08);
+      }
+
+      /* Tightest possible workspaces */
+      #workspaces { padding: 0; margin: 0; }
+      #workspaces button {
+        margin: 0;
+        padding: 0 3px;
+        min-width: 0;
+        border-radius: 0;
+        background: transparent;
+        color: #cfcfcf;
+      }
+      #workspaces button:hover {
+        background: rgba(255, 255, 255, 0.06);
+      }
+      #workspaces button.active,
+      #workspaces button.focused {
+        background: rgba(255, 255, 255, 0.10);
+        color: #ffffff;
+        box-shadow: inset 0 -2px #ffffff;
+      }
+      #workspaces button.urgent {
+        background: rgba(255, 80, 80, 0.25);
+        box-shadow: inset 0 -2px #ff5050;
+      }
+
+      /* Focused window title: single line, no glow */
+      #window {
+        padding: 0 6px;
+        margin: 0;
+        color: #dedede;
+      }
+
+      /* Sway mode indicator: visible only when active, no bloat */
+      #mode {
+        padding: 0 6px;
+        margin: 0;
+        background: rgba(255, 255, 255, 0.10);
+        color: #ffffff;
+        box-shadow: inset 0 -2px #ffffff;
+      }
+
+      /* Status modules — keep them flat and compact */
+      #clock, #battery, #network, #pulseaudio, #backlight, #cpu, #memory, #temperature, #tray {
+        padding: 0 6px;
+        margin: 0;
+        background: transparent;
+        color: #eaeaea;
+      }
+
+      /* States (battery, network, audio) */
+      #battery.charging { color: #27f902; }
+      #battery.warning:not(.charging) { color: #fc8b02; }
+      #battery.critical:not(.charging) { color: #fc0000; }
+
+      #network.disconnected { color: #ffb4b4; }
+      #pulseaudio.muted    { color: #9aa0a6; }
+
+      /* Tray: compress icons */
+      #tray > .passive { opacity: 0.6; }
+      #tray > .needs-attention { opacity: 1; }
+
+      /* Tooltips: clean and readable */
+      tooltip {
+        background: rgba(30, 30, 30, 0.95);
+        border: 1px solid rgba(255, 255, 255, 0.08);
+        color: #eaeaea;
+        padding: 6px 8px;
+      }
+
+      /* Remove any leftover borders around everything */
+      #custom-*, #idle_inhibitor, #privacy, #bluetooth {
+        border: none;
+        background: transparent;
+        margin: 0;
+        padding: 0 6px;
+      }
+    '';
+  };
+}
diff --git a/modules/waybar/options.nix b/modules/waybar/options.nix
new file mode 100644
index 0000000..b2daa33
--- /dev/null
+++ b/modules/waybar/options.nix
@@ -0,0 +1,23 @@
+{lib, ...}:
+with lib.types; {
+  hm = {
+    battery = lib.mkOption {
+      type = bool;
+      default = false;
+      description = ''
+        `true` to display battery info
+      '';
+    };
+    fontFamily = lib.mkOption {
+      type = str;
+      example = "JetBrainsMono Nerd Font";
+      description = ''
+        needs to be a nerdfont
+      '';
+    };
+    fontSize = lib.mkOption {
+      type = str;
+      default = "12px";
+    };
+  };
+}
diff --git a/modules/yubico/default.nix b/modules/yubico/default.nix
new file mode 100644
index 0000000..71bed70
--- /dev/null
+++ b/modules/yubico/default.nix
@@ -0,0 +1,13 @@
+{
+  config,
+  lib,
+  pkgs,
+  doctrine,
+  ...
+}:
+doctrine.lib.mkModule {
+  inherit config;
+  name = "yubico";
+  hm = ./hm.nix;
+  sys = ./sys.nix;
+}
diff --git a/modules/yubico/hm.nix b/modules/yubico/hm.nix
new file mode 100644
index 0000000..8d06368
--- /dev/null
+++ b/modules/yubico/hm.nix
@@ -0,0 +1,9 @@
+{
+  pkgs,
+  lib,
+  ...
+}: {
+  home.packages = [
+    pkgs.yubikey-manager
+  ];
+}
diff --git a/modules/yubico/sys.nix b/modules/yubico/sys.nix
new file mode 100644
index 0000000..3cd009f
--- /dev/null
+++ b/modules/yubico/sys.nix
@@ -0,0 +1,14 @@
+{
+  pkgs,
+  lib,
+  ...
+}: {
+  environment.etc."pkcs11/modules/ykcs11".text = ''
+    module: ${pkgs.yubico-piv-tool}/lib/libykcs11.so
+  '';
+
+  services = {
+    pcscd.enable = true;
+    udev.packages = [pkgs.yubikey-personalization];
+  };
+}
diff --git a/nixos/default.nix b/nixos/default.nix
deleted file mode 100644
index e2637ac..0000000
--- a/nixos/default.nix
+++ /dev/null
@@ -1,11 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}: {
-  imports = [
-    ./trash
-    ./services
-  ];
-}
diff --git a/nixos/services/default.nix b/nixos/services/default.nix
deleted file mode 100644
index 36b456a..0000000
--- a/nixos/services/default.nix
+++ /dev/null
@@ -1,10 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}: {
-  imports = [
-    ./forgejo
-  ];
-}
diff --git a/nixos/services/forgejo/default.nix b/nixos/services/forgejo/default.nix
deleted file mode 100644
index b15d2d9..0000000
--- a/nixos/services/forgejo/default.nix
+++ /dev/null
@@ -1,66 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}:
-with lib; let
-  cfg = config.options.trivium.services.forgejo;
-in {
-  options.trivium.services.forgejo = {
-    enable = mkEnableOption "forgejo settings";
-
-    virtualHost = mkOption {
-      type = types.string;
-      description = "Virtualhost to use for nginx's reverse proxy. Usually something like git.<your server>.com";
-    };
-
-    appName = mkOption {
-      type = types.string;
-      description = "You guess what this does";
-    };
-
-    disableRegistration = mkOption {
-      type = types.bool;
-      default = true;
-      description = "Turn this off just to create the first admin account";
-    };
-  };
-
-  config = mkIf cfg.enable {
-    services = {
-      nginx = {
-        virtualHosts."${cfg.virtualHost}" = {
-          enableACME = true;
-          forceSSL = true;
-          locations."/".proxyPass = "http://localhost:9170";
-        };
-      };
-
-      forgejo = {
-        enable = true;
-        lfs.enable = true;
-        useWizard = false;
-        settings = {
-          general.APP_NAME = "${cfg.appName}";
-          ui.DEFAULT_THEME = "forgejo-dark";
-          server = {
-            DOMAIN = "${cfg.virtualHost}";
-            ROOT_URL = "https://${cfg.virtualHost}";
-            HTTP_PORT = 9170;
-            LANDING_PAGE = "explore";
-          };
-
-          service.DISABLE_REGISTRATION = ${cfg.disableRegistration};
-
-          actions = {
-            ENABLED = true;
-          };
-          mailer = {
-            ENABLED = false;
-          };
-        };
-      };
-    };
-  };
-}
diff --git a/nixos/trash/default.nix b/nixos/trash/default.nix
deleted file mode 100644
index a8c8785..0000000
--- a/nixos/trash/default.nix
+++ /dev/null
@@ -1,10 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}: {
-  imports = [
-    ./steam
-  ];
-}
diff --git a/nixos/trash/steam/default.nix b/nixos/trash/steam/default.nix
deleted file mode 100644
index 80a45e8..0000000
--- a/nixos/trash/steam/default.nix
+++ /dev/null
@@ -1,55 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}:
-with lib; let
-  cfg = config.options.trivium.trash.steam;
-in {
-  options.trivium.trash.steam = {
-    enable = mkEnableOption "steam settings";
-
-    compatibilityPackages = mkOption {
-      type = types.bool;
-      default = true;
-      description = "Enable additional compatibility packages (protontricks, protonup, etc.)";
-    };
-
-    remotePlayOpenFirewall = mkOption {
-      type = types.bool;
-      default = false;
-      description = "Open firewall for Steam Remote Play";
-    };
-
-    dedicatedServerOpenFirewall = mkOption {
-      type = types.bool;
-      default = false;
-      description = "Open firewall for Steam Dedicated Server";
-    };
-
-    localNetworkGameTransfersOpenFirewall = mkOption {
-      type = types.bool;
-      default = false;
-      description = "Open firewall for Steam Local Network Game Transfers";
-    };
-  };
-
-  config = mkIf cfg.enable {
-    programs.steam = {
-      enable = true;
-      remotePlay.openFirewall = cfg.remotePlayOpenFirewall;
-      dedicatedServer.openFirewall = cfg.dedicatedServerOpenFirewall;
-      localNetworkGameTransfers.openFirewall = cfg.localNetworkGameTransfersOpenFirewall;
-    };
-
-    environment = mkIf cfg.compatibilityPackages {
-      systemPackages = with pkgs; [
-        protontricks
-        protonup
-        protonup-ng
-        winetricks
-      ];
-    };
-  };
-}
diff --git a/pkgs/athena-bccr/0001-Remove-CheckUpdatePlugin-from-default-list.patch b/pkgs/athena-bccr/0001-Remove-CheckUpdatePlugin-from-default-list.patch
new file mode 100644
index 0000000..e7fc5d5
--- /dev/null
+++ b/pkgs/athena-bccr/0001-Remove-CheckUpdatePlugin-from-default-list.patch
@@ -0,0 +1,25 @@
+From 5e7eb46f46af6a29a2aea19db722ebc28baede25 Mon Sep 17 00:00:00 2001
+From: Alejandro Soto <alejandro@34project.org>
+Date: Sat, 21 Jun 2025 22:37:19 -0600
+Subject: [PATCH] Remove CheckUpdatePlugin from default list
+
+---
+ src/main/java/cr/libre/firmador/Settings.java | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/src/main/java/cr/libre/firmador/Settings.java b/src/main/java/cr/libre/firmador/Settings.java
+index e5ddf01..a028d6e 100644
+--- a/src/main/java/cr/libre/firmador/Settings.java
++++ b/src/main/java/cr/libre/firmador/Settings.java
+@@ -81,7 +81,7 @@ public class Settings {
+ 
+     public Settings() {
+         activePlugins.add("cr.libre.firmador.plugins.DummyPlugin");
+-        activePlugins.add("cr.libre.firmador.plugins.CheckUpdatePlugin");
++        // activePlugins.add("cr.libre.firmador.plugins.CheckUpdatePlugin");
+         availablePlugins.add("cr.libre.firmador.plugins.DummyPlugin");
+         availablePlugins.add("cr.libre.firmador.plugins.CheckUpdatePlugin");
+     }
+-- 
+2.49.0
+
diff --git a/pkgs/athena-bccr/LaunchGaudi.java b/pkgs/athena-bccr/LaunchGaudi.java
new file mode 100644
index 0000000..e4bcdbf
--- /dev/null
+++ b/pkgs/athena-bccr/LaunchGaudi.java
@@ -0,0 +1,12 @@
+// Los del BCCR no se molestaron en ponerle un main al Agente Gaudi porque el
+// actualizador (que a su vez sí tiene main) carga el jar en memoria y crea una
+// instancia de Inicializador usando reflexión. El actualizador no es relevante
+// en Nix. En todo caso, dicho actualizador es sumamente frágil y me daría
+// demasiada pereza arreglarlo, así que en su lugar usamos este stub para
+// launchear Gaudi.
+
+public class LaunchGaudi {
+	public static void main(String[] args) {
+		new InicializadorCliente.Inicializador("");
+	}
+}
diff --git a/pkgs/athena-bccr/default.nix b/pkgs/athena-bccr/default.nix
new file mode 100644
index 0000000..a5f79ca
--- /dev/null
+++ b/pkgs/athena-bccr/default.nix
@@ -0,0 +1,30 @@
+{
+  callPackage,
+  lib,
+}: let
+  latest = "deb64-rev26";
+
+  releases = lib.mapAttrs (name: release: release // {name = name;}) (import ./releases.nix);
+
+  overrideUnwrapped = default: new: let
+    args = default // new;
+    unwrappedPkgs = lib.filterAttrs (name: _: ! lib.elem name ["override" "overrideDerivation"]) (callPackage ./unwrapped.nix args);
+  in
+    lib.fix (unwrapped: lib.mapAttrs (_: pkg: callPackage pkg unwrapped) unwrappedPkgs)
+    // {
+      override = overrideUnwrapped args;
+    };
+
+  pkgsForRelease = release: let
+    ase-pkcs11 = unwrapped.ase-idprotect.lib;
+    libasep11 = "${ase-pkcs11}/lib/x64-athena/libASEP11.so";
+    unwrapped = overrideUnwrapped {inherit release;} {};
+  in {
+    inherit ase-pkcs11 libasep11;
+    inherit (unwrapped) ase-idprotect bccr-cacerts;
+
+    gaudi = callPackage ./gaudi-env.nix {inherit unwrapped;};
+    firmador = callPackage ./firmador.nix {inherit libasep11;};
+  };
+in
+  lib.mapAttrs (_: pkgsForRelease) (releases // {latest = releases.${latest};})
diff --git a/pkgs/athena-bccr/firmador.nix b/pkgs/athena-bccr/firmador.nix
new file mode 100644
index 0000000..d280b56
--- /dev/null
+++ b/pkgs/athena-bccr/firmador.nix
@@ -0,0 +1,57 @@
+{
+  fetchgit,
+  lib,
+  makeWrapper,
+  maven,
+  openjdk,
+  wrapGAppsHook,
+  libasep11 ? null,
+}: let
+  jdk = openjdk.override {
+    enableJavaFX = true;
+  };
+
+  version = "1.9.8";
+in
+  maven.buildMavenPackage {
+    pname = "firmador";
+    inherit version;
+
+    src = fetchgit {
+      url = "https://codeberg.org/firmador/firmador";
+      rev = version;
+      hash = "sha256-xdiVPjihRADPK4nG+WQHWsDzVYLCeN6ouQ6SDtjf1qQ=";
+    };
+
+    patches = [
+      ./0001-Remove-CheckUpdatePlugin-from-default-list.patch
+    ];
+
+    mvnHash = "sha256-h1zoStTgaE7toWWKq0Y0ahOORyltChwjmaMYjLgs1VE=";
+
+    nativeBuildInputs = [
+      makeWrapper
+      wrapGAppsHook
+    ];
+
+    postPatch = lib.optionalString (libasep11 != null) ''
+      sed -i 's@/usr/lib/x64-athena/libASEP11.so@${libasep11}@g' src/main/java/cr/libre/firmador/CRSigner.java
+    '';
+
+    installPhase = ''
+      runHook preInstall
+
+      mkdir -p $out/bin $out/share/java
+      install -Dm644 target/firmador.jar $out/share/java
+
+      makeWrapper ${jdk}/bin/java $out/bin/firmador \
+        --add-flags "-jar $out/share/java/firmador.jar"
+
+      runHook postInstall
+    '';
+
+    meta = {
+      homepage = "https://firmador.libre.cr";
+      license = lib.licenses.gpl3Plus;
+    };
+  }
diff --git a/pkgs/athena-bccr/gaudi-env.nix b/pkgs/athena-bccr/gaudi-env.nix
new file mode 100644
index 0000000..0ca1b82
--- /dev/null
+++ b/pkgs/athena-bccr/gaudi-env.nix
@@ -0,0 +1,62 @@
+{
+  buildFHSEnv,
+  curl,
+  lib,
+  writeShellScriptBin,
+  gaudiHash ? null,
+  unwrapped,
+}: let
+  unwrappedWithGaudi = unwrapped.override {inherit gaudiHash;};
+in
+  buildFHSEnv {
+    name = "gaudi";
+
+    targetPkgs = pkgs: [
+      unwrappedWithGaudi.ase-idprotect.lib
+      unwrappedWithGaudi.gaudi
+
+      (writeShellScriptBin "launch-gaudi" ''
+        set -o errexit
+        set -o pipefail
+        set -o nounset
+
+        PATH="${lib.makeBinPath [curl]}:$PATH"
+
+        echo "$0: testing for incompatible releases..." >&2
+
+        jar_name=bccr-firma-fva-clienteMultiplataforma.jar
+        url="https://www.firmadigital.go.cr/Bccr.Firma.Fva.Actualizador.ClienteFirmadorJava//recursosLiberica17/actualizador/$jar_name"
+        ca_file="${unwrappedWithGaudi.bccr-cacerts}/root-ca.pem"
+        url_hash=$(curl -sS --cacert "$ca_file" "$url" | sha256sum | cut -d' ' -f1)
+        jar_path="${unwrappedWithGaudi.gaudi}/share/java/$jar_name"
+        jar_hash=$(sha256sum "$jar_path" | cut -d' ' -f1)
+
+        if [ "$url_hash" != "$jar_hash" ]; then
+          last_modified=$(curl -sS --head --cacert "$ca_file" "$url" | grep -i '^last-modified:' | head -1)
+
+          echo "$0: sha256 mismatch for $jar_path due to server-side update" >&2
+          echo "$0:   expected:      $url_hash" >&2
+          echo "$0:   actual:        $jar_hash" >&2
+          echo "$0:   $last_modified" >&2
+          echo "$0: run the following to download the new client JAR, then update your derivation:" >&2
+          echo "$0: \$ ${unwrappedWithGaudi.update-gaudi}" >&2
+
+          exit 1
+        fi
+
+        cache_path_1="''${XDG_CACHE_HOME:-$HOME/.cache}/Agente-GAUDI"
+        cache_path_2="''${XDG_CACHE_HOME:-$HOME/.cache}/Firmador-BCCR"
+
+        for cache_path in "$cache_path_1" "$cache_path_2"; do
+          mkdir -p "$cache_path"
+          ln -sf -- ${unwrappedWithGaudi.gaudi}/share/java/bccr-firma-fva-clienteMultiplataforma.jar "$cache_path"
+        done
+
+        cp -f --no-preserve=mode -t "$cache_path_1" -- "${unwrappedWithGaudi.gaudi}/share/java/config.properties"
+
+        exec gaudi
+      '')
+    ];
+
+    runScript = "launch-gaudi";
+  }
diff --git a/pkgs/athena-bccr/releases.nix b/pkgs/athena-bccr/releases.nix
new file mode 100644
index 0000000..e965172
--- /dev/null
+++ b/pkgs/athena-bccr/releases.nix
@@ -0,0 +1,12 @@
+{
+  "deb64-rev26" = {
+    # nix hash convert --hash-algo sha256 --from base16 --to sri $(sha256sum sfd_ClientesLinux_DEB64_Rev26.zip | cut -d' ' -f1)
+    hash = "sha256-ZPWP9TqJQ5coJAPzUSiaXKVItBWlqFM4smCjOf+gqQM=";
+    basename = "sfd_ClientesLinux_DEB64_Rev26";
+
+    srcPaths = {
+      gaudi = "Firma Digital/Agente GAUDI/agente-gaudi_20.0_amd64.deb";
+      idprotect = "Firma Digital/PinTool/IDProtect PINTool 7.24.02/DEB/idprotectclient_7.24.02-0_amd64.deb";
+    };
+  };
+}
diff --git a/pkgs/athena-bccr/unwrapped.nix b/pkgs/athena-bccr/unwrapped.nix
new file mode 100644
index 0000000..d6f3f38
--- /dev/null
+++ b/pkgs/athena-bccr/unwrapped.nix
@@ -0,0 +1,226 @@
+{
+  lib,
+  requireFile,
+  release,
+  gaudiHash ? null,
+  ...
+}: let
+  inherit (release) srcPaths;
+
+  src = requireFile {
+    url = "https://soportefirmadigital.com";
+    name = "${release.basename}.zip";
+
+    inherit (release) hash;
+  };
+
+  gaudiUpdateSrc = {update-gaudi}:
+    requireFile {
+      url = "${update-gaudi}";
+      name = "gaudi-update-${release.name}.zip";
+
+      hash = gaudiHash;
+    };
+
+  moduleFromDeb = name: args @ {
+    stdenv,
+    dpkg,
+    unzip,
+    srcPath,
+    ...
+  }:
+    stdenv.mkDerivation ({
+        pname = "${name}-unwrapped";
+        version = release.name;
+
+        inherit src;
+
+        nativeBuildInputs = [dpkg unzip] ++ (args.nativeBuildInputs or []);
+
+        postUnpack = ''
+          dpkg -x ${lib.escapeShellArg "${release.basename}/${srcPath}"} ${lib.escapeShellArg release.basename}
+        '';
+      }
+      // lib.removeAttrs args ["stdenv" "dpkg" "unzip" "srcPath" "nativeBuildInputs"]);
+in {
+  ase-idprotect = {
+    autoPatchelfHook,
+    dpkg,
+    fontconfig,
+    freetype,
+    pcsclite,
+    stdenv,
+    unzip,
+    xorg,
+    zlib,
+    ...
+  }:
+    moduleFromDeb "ase-idprotect" {
+      inherit dpkg stdenv unzip;
+      srcPath = srcPaths.idprotect;
+
+      buildInputs = [
+        fontconfig
+        freetype
+        pcsclite
+        stdenv.cc.cc.lib
+        xorg.libX11
+        xorg.libXext
+        zlib
+      ];
+
+      nativeBuildInputs = [
+        autoPatchelfHook
+      ];
+
+      outputs = ["out" "lib"];
+
+      installPhase = ''
+        runHook preInstall
+
+        install -m755 -d $out/bin $lib/{etc,lib/x64-athena}
+        install -m755 usr/bin/IDProtect{_Manager,PINTool} $out/bin/
+        install -m755 usr/lib/x64-athena/* $lib/lib/x64-athena
+        cp -r etc/Athena $lib/etc/Athena
+
+        runHook postInstall
+      '';
+
+      preFixup = ''
+        patchelf --set-rpath $lib/lib/x64-athena $out/bin/*
+      '';
+    };
+
+  gaudi = {
+    autoPatchelfHook,
+    dpkg,
+    makeWrapper,
+    openjdk,
+    pkgs,
+    stdenv,
+    unzip,
+    writeShellScriptBin,
+    update-gaudi,
+    ...
+  }: let
+    jdk = openjdk.override {
+      enableJavaFX = true;
+      openjfx_jdk = pkgs."openjfx${lib.head (lib.splitString "." openjdk.version)}".override {withWebKit = true;};
+    };
+
+    fakeSudo = writeShellScriptBin "sudo" "";
+    gaudiUpdate = gaudiUpdateSrc {inherit update-gaudi;};
+  in
+    moduleFromDeb "gaudi" {
+      inherit dpkg stdenv unzip;
+      srcPath = srcPaths.gaudi;
+
+      nativeBuildInputs = [
+        autoPatchelfHook
+        jdk
+        makeWrapper
+      ];
+
+      preBuild = lib.optionalString (gaudiHash != null) ''
+        unzip -o ${gaudiUpdate} -d opt/Agente-GAUDI/lib/app
+      '';
+
+      buildPhase = ''
+        runHook preBuild
+
+        install -m755 -d $out/{bin,opt/Firmador-BCCR/lib}
+        cp -r opt/Agente-GAUDI/lib/app $out/opt/Firmador-BCCR/lib/app
+
+        # Preserves the original filename and avoids <hash>-LaunchGaudi.java
+        ln -s ${./LaunchGaudi.java} LaunchGaudi.java
+
+        javac \
+          -cp opt/Agente-GAUDI/lib/app/bccr-firma-fva-clienteMultiplataforma.jar \
+          -d $out/opt/Firmador-BCCR/lib/app \
+          LaunchGaudi.java
+
+        runHook postBuild
+      '';
+
+      installPhase = ''
+        runHook preInstall
+
+        install -m755 -d $out/{share,opt/Firmador-BCCR/lib/runtime/lib}
+        install -m755 -D opt/Agente-GAUDI/bin/Agente-GAUDI $out/opt/Firmador-BCCR/bin/Agente-GAUDI
+        install -m755 -D opt/Agente-GAUDI/lib/libapplauncher.so $out/opt/Firmador-BCCR/lib/libapplauncher.so
+
+        ln -s ../opt/Firmador-BCCR/lib/app $out/share/java
+        ln -s Firmador-BCCR $out/opt/Agente-GAUDI
+        ln -s ${jdk}/lib/openjdk/lib/libjli.so $out/opt/Firmador-BCCR/lib/runtime/lib/libjli.so
+
+        makeWrapper ${jdk}/bin/java $out/bin/gaudi \
+          --prefix PATH : ${fakeSudo}/bin \
+          --add-flags "-cp $out/share/java:$out/share/java/bccr-firma-fva-clienteMultiplataforma.jar" \
+          --add-flags "-Djavax.net.ssl.trustStore=$out/opt/Firmador-BCCR/lib/app/bccr.cacerts" \
+          --add-flags "LaunchGaudi"
+
+        runHook postInstall
+      '';
+    };
+
+  bccr-cacerts = {
+    openssl,
+    stdenv,
+    unzip,
+    ...
+  }:
+    stdenv.mkDerivation {
+      pname = "bccr-cacerts";
+      version = release.name;
+
+      inherit src;
+
+      nativeBuildInputs = [
+        openssl
+        unzip
+      ];
+
+      installPhase = ''
+        cp -r Firma\ Digital/Certificados $out
+        openssl x509 -in $out/CA\ RAIZ\ NACIONAL\ -\ COSTA\ RICA\ v2.crt -out $out/root-ca.pem -text
+      '';
+    };
+
+  update-gaudi = {
+    wget,
+    writeShellScript,
+    zip,
+    bccr-cacerts,
+    ...
+  }:
+    writeShellScript "update-gaudi" ''
+      set -o errexit
+      set -o pipefail
+      set -o nounset
+
+      temp_dir="$(mktemp -d)"
+      trap 'cd / && rm -rf -- "$temp_dir"' EXIT
+      cd "$temp_dir"
+
+      PATH="${lib.makeBinPath [wget zip]}:$PATH"
+      ca_cert="${bccr-cacerts}/root-ca.pem"
+      base_url="https://www.firmadigital.go.cr/Bccr.Firma.Fva.Actualizador.ClienteFirmadorJava//recursosLiberica17/actualizador"
+
+      wget --ca-certificate="$ca_cert" "$base_url/bccr.cacerts"
+      wget --ca-certificate="$ca_cert" "$base_url/config.properties"
+      wget --ca-certificate="$ca_cert" "$base_url/bccr-firma-fva-clienteMultiplataforma.jar"
+      wget --ca-certificate="$ca_cert" "$base_url/ServicioActualizadorClienteBCCR.jar"
+
+      # https://gist.github.com/stokito/c588b8d6a6a0aee211393d68eea678f2
+      TZ=UTC find . -exec touch --no-dereference -a -m -t 198002010000.00 {} +
+      zip_path="$PWD/gaudi-update-${release.name}.zip"
+      TZ=UTC zip -q --move --recurse-paths --symlinks -X "$zip_path" .
+      TZ=UTC touch -a -m -t 198002010000.00 "$zip_path"
+
+      set -x
+      nix-store --add-fixed sha256 "$zip_path"
+      set +x
+
+      echo -e "\ngaudiHash: $(nix-hash --to-sri --type sha256 $(sha256sum "$zip_path" | cut -d' ' -f1))"
+    '';
+}
diff --git a/pkgs/default.nix b/pkgs/default.nix
index 2ee6bfd..4a275a3 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -2,7 +2,9 @@ final: prev:
 with prev.lib; let
   inherit (final) callPackage;
 in {
-  lib = callPackage ./lib {};
-
   override = {};
+
+  athena-bccr = callPackage ./athena-bccr {};
+  snapborg = final.python3Packages.callPackage ./snapborg {};
+  spliit = callPackage ./spliit {};
 }
diff --git a/pkgs/lib/default.nix b/pkgs/lib/default.nix
deleted file mode 100644
index e3ab56e..0000000
--- a/pkgs/lib/default.nix
+++ /dev/null
@@ -1,3 +0,0 @@
-{callPackage}: {
-  importAll = callPackage ./importAll.nix {};
-}
diff --git a/pkgs/snapborg/0001-Remove-env-arg-from-subprocess-calls.patch b/pkgs/snapborg/0001-Remove-env-arg-from-subprocess-calls.patch
new file mode 100644
index 0000000..33f7a0c
--- /dev/null
+++ b/pkgs/snapborg/0001-Remove-env-arg-from-subprocess-calls.patch
@@ -0,0 +1,29 @@
+From c363931656938f9cc3354b8e2797fe9abac1b0e3 Mon Sep 17 00:00:00 2001
+From: Alejandro Soto <alejandro@34project.org>
+Date: Sun, 31 Aug 2025 13:30:45 -0600
+Subject: [PATCH] Remove "env" arg from subprocess calls
+
+---
+ snapborg/borg.py | 3 +--
+ 1 file changed, 1 insertion(+), 2 deletions(-)
+
+diff --git a/snapborg/borg.py b/snapborg/borg.py
+index 89a3d84..b74ddf7 100644
+--- a/snapborg/borg.py
++++ b/snapborg/borg.py
+@@ -173,11 +173,10 @@ def launch_borg(args, password=None, print_output=False, dryrun=False, cwd=None)
+         # TODO: parse output from JSON log lines
+         try:
+             if print_output:
+-                subprocess.run(cmd, env=env, check=True, cwd=cwd)
++                subprocess.run(cmd, check=True, cwd=cwd)
+             else:
+                 subprocess.check_output(cmd,
+                                         stderr=subprocess.STDOUT,
+-                                        env=env,
+                                         cwd=cwd)
+         except CalledProcessError as e:
+             if e.returncode == 1:
+-- 
+2.49.0
+
diff --git a/pkgs/snapborg/default.nix b/pkgs/snapborg/default.nix
new file mode 100644
index 0000000..271be5c
--- /dev/null
+++ b/pkgs/snapborg/default.nix
@@ -0,0 +1,34 @@
+{
+  borgbackup,
+  buildPythonApplication,
+  fetchFromGitHub,
+  lib,
+  packaging,
+  pyyaml,
+}:
+buildPythonApplication {
+  pname = "snapborg";
+  version = "0.1.0-unstable-20250331";
+
+  src = fetchFromGitHub {
+    repo = "snapborg";
+    owner = "enzingerm";
+
+    rev = "7e860395319f995161a6e0c7954ce47635e3cd59";
+    hash = "sha256-RzYL4IHulk1Q/ALWFs6YCTeCO8ohwqXH2NMHRctRVSA=";
+  };
+
+  patches = [
+    ./0001-Remove-env-arg-from-subprocess-calls.patch # Fixes broken $PATH when calling borg
+  ];
+
+  propagatedBuildInputs = [
+    borgbackup
+    packaging
+    pyyaml
+  ];
+
+  preFixup = ''
+    makeWrapperArgs+=(--prefix PATH : ${lib.makeBinPath [borgbackup]})
+  '';
+}
diff --git a/pkgs/spliit/default.nix b/pkgs/spliit/default.nix
new file mode 100644
index 0000000..280e820
--- /dev/null
+++ b/pkgs/spliit/default.nix
@@ -0,0 +1,76 @@
+{
+  buildNpmPackage,
+  fetchFromGitHub,
+  nodePackages,
+  lib,
+  writeShellScriptBin,
+  pkgs,
+}: let
+  schemaEngine = "${pkgs.prisma-engines}/bin/schema-engine";
+  queryEngineBin = "${pkgs.prisma-engines}/bin/query-engine";
+  queryEngineLib = "${pkgs.prisma-engines}/lib/libquery_engine.node";
+  buildFlags = ["--ignore-scripts"];
+in
+  buildNpmPackage {
+    pname = "spliit2";
+    version = "master-20250420";
+
+    src = fetchFromGitHub {
+      repo = "spliit";
+      owner = "spliit-app";
+
+      rev = "a11efc79c13298c0d282e47496d132538752405f";
+      hash = "sha256-v4gaPzLzBbbqw/LDYxe1fiyficcrqcGOop23YPiTrdc=";
+    };
+
+    npmDepsHash = "sha256-sd0/7ruNUFxUKTeTwx/v8Vc/G3llkXP6RSDE78h3qVU=";
+
+    nativeBuildInputs = [pkgs.openssl];
+
+    npmRebuildFlags = buildFlags;
+
+    PRISMA_SCHEMA_ENGINE_BINARY = schemaEngine;
+    PRISMA_QUERY_ENGINE_BINARY = queryEngineBin;
+    PRISMA_QUERY_ENGINE_LIBRARY = queryEngineLib;
+
+    preBuild = ''
+      cp -v scripts/build.env .env
+
+      npx prisma generate
+    '';
+
+    npmBuildFlags = buildFlags;
+
+    postInstall = ''
+      cp -r .next public package.json next.config.mjs $out/lib/node_modules/spliit2
+
+      install -Dvm755 -t $out/bin ${lib.getExe (writeShellScriptBin "spliit2" ''
+        set -euxo pipefail
+
+        cd @out@/lib/node_modules/spliit2
+
+        export PATH="$PWD/node_modules/.bin:$PATH"
+        export NEXT_TELEMETRY_DISABLED=1
+
+        export PRISMA_SCHEMA_ENGINE_BINARY="${schemaEngine}"
+        export PRISMA_QUERY_ENGINE_BINARY="${queryEngineBin}"
+        export PRISMA_QUERY_ENGINE_LIBRARY="${queryEngineLib}"
+
+        prisma migrate deploy
+        next start
+      '')}
+
+      substituteInPlace $out/bin/spliit2 \
+        --replace @out@ $out
+
+      wrapProgram $out/bin/spliit2 \
+        --prefix PATH : ${lib.makeBinPath [pkgs.openssl]}
+    '';
+
+    meta = {
+      description = "Free and Open Source Alternative to Splitwise. Share expenses with your friends and family.";
+      homepage = "https://spliit.app";
+      license = lib.licenses.mit;
+      maintainers = with lib.maintainers; [];
+    };
+  }